Task: Rename a Project with a Windows Batch (.bat) File

• Permissions Required
• Other Requirements
• The Renaming Batch File
• Using the Batch File
• Modifying the Batch File
• Writing Other Batch Files
• Running Batch Files Automatically
• Links

Permissions Required

The file requires that special user Anonymous has the following permissions for the project P of interest.

• PROJECT_READ P
• PROJECT_WRITE P

If you will be extending the script to derive the project ID from an analysis directory for some analysis A of the project, you will also need the following permissions for A.

• ANALYSIS_READ A

See Modifying the Batch File for information on modifying the file to specify credentials for a non-Anonymous user with the required permissions.

Other Requirements

The Renaming Batch File

The following file will change the name of

• the project whose project ID matches the second argument passed to the file,
• on the hub specified in the first argument to the file,
• to the value specified in the third argument to the file.

@ECHO off
set HUB=%1
set PROJECT_ID=%2
set NEW_NAME=%3

set PROJECT_HTML_URL=%HUB%/project/%PROJECT_ID%.html
set CURL_CMD=curl

:: The Project file has exactly one line containing substring 
:: 'old_name_hash', and the hash value is between the 7th and 8th
:: (1-based) double quotes on that line.

FOR /F delims^=^"^ tokens^=8  %%i IN ('%CURL_CMD% %PROJECT_HTML_URL% ^| findstr -r "old_name_hash" 2^>nul') DO set OLD_NAME_HASH=%%i

(%CURL_CMD% -d old_name_hash=%OLD_NAME_HASH% -d new_name=%NEW_NAME% %PROJECT_HTML_URL%)

exit /b

This batch file uses an HTTP POST request to send the new project name to the hub, just as the web form on the Project page would do if you were changing the name in the web GUI. It outputs the updated Project page HTML.

Note that the HTTP POST request must include both the new project name (new_name) and CodeSonar's hash of the current project name (old_name_hash). The CodeSonar hub requires the hash value as a consistency check, so the script must recover it from a separate initial page request.

Using the Batch File

To use this file with your hub, do the following.

1. Copy rename_project.bat to a suitable directory. The remainder of these instructions will refer to this directory as rundir.
2. Run the file:
   cd rundir
   rename_project protocol://host:port pid newname
   where

   protocol	is the protocol for your hub: http or https.
   host:port	is the location of your hub.
   pid	is the project ID for the project whose name you wish to change. You can find the project ID: in the GUI Project page URL, which will be of the form http://hub_location/project/project_id.html, or by deriving it based on the analysis ID from the most recent analysis of the project, which in turn is available: in the URL specified at the end build/analysis command output, which will be of the form http://hub_location/analysis/analysis_id.html, or by running the following command, where path\to\projname.prj_files\ is the analysis directory codesonar analysis_id.py path\to\projname.prj_files\ or in file path\to\projname.prj_files\aid.txt, where path\to\projname.prj_files\ is the analysis directory. For details, see Derive the project ID from the analysis directory, below.
   newname	is new name you wish to set for the project. It must be URL-encoded.

   The file will output information about its progress.
3. Open the project page protocol://host:port/project/pid.html in your web browser to confirm that its name has changed (or look at the top of the output).

Invocation Example

Using the hub at http://[::1]:7341, change the name of the project with ID 3 to "My Renamed Project ":

• Note the URL-encoding of the new name.

Troubleshooting

set CURL_CMD=curl -v

Modifying the Batch File

You may wish to make one or more of the following modifications.

• Stop printing the updated HTML file to output
• Derive the project ID from the analysis directory
• Provide credentials for a non-Anonymous user

Stop printing the updated HTML file to output

If you don't want to see the updated HTML file as part of your script's output, you can redirect it to the null location by modifying your curl command. Note that if you make further changes that you need to debug later, you may wish to lift this suppression at least temporarily.

1. Edit rename_project.bat so that curl is invoked with the -o flag and a suitable value.

   set CURL_CMD=curl -o nul

Derive the project ID from the analysis directory

Instead of specifying the project ID on the command line, you can change the file to read the analysis directory from the command line and derive the project ID by reading the most recent analysis ID from the analysis directory, requesting the corresponding Analysis page from the hub, then reading the project ID from the Analysis page.

Because this approach requires the Analysis page for the analysis A in question, you must have the following permissions for A in addition to the required project permissions.

• ANALYSIS_READ A

Once you have verified that you have these permissions, proceed as follows.

1. Edit rename_project.bat so that the line setting ANALYSIS_ID is replaced with three lines:

   set ANALYSIS_DIR=%2
   set CSONAR=codesonar.exe
   for /F "tokens=*" %%g in ('%CSONAR% analysis_id.py %ANALYSIS_DIR%') do (set ANALYSIS_ID=%%g)
   

   If it is not in your PATH, adjust the setting of CSONAR to include the full path to your codesonar.exe executable.
2. Delete the line setting PROJECT_HTML_URL and replace it with the following line setting ANALYSIS_HTML_URL.

   ANALYSIS_HTML_URL='{0}/analysis/{1}.html'.format(HUB,ANALYSIS_ID)

3. Insert the following code at the end of the batch file (after the existing exit /b line). This new function downloads a page using the URL in its first argument, searches the page for the first occurrence of a partial Project page URL, then extracts the ID from the URL and returns it through the second argument.

   :pid_from_analysis_page
   set URL=%1
   
   :: The Analysis page breadcrumbs contain a link of the form
   :: <a href="/project/project_id.html">.
   :: Get the LINE containing this link.
   
   FOR /F "delims=" %%i IN ('%CURL_CMD% %URL% ^| findstr -r  /c:"<a href=\"/project\/[0-9]*.html\"" 2^>nul') DO set LINE=%%i
   
   :: Remove problematic special characters from LINE, then
   :: find the SUBLINE that occurs between '/project/' and the next '/'
   set "LINE=%LINE: =%"
   set "LINE=%LINE:"=%"
   set SUBLINE=""
   set /A PRJ_SEEN=0
   set /A COUNTER=0
   
   :LOOPBEGIN
   set /A COUNTER+=1
   FOR /F  "delims=/ tokens=%COUNTER%" %%A IN ("%LINE%") DO (
       if %PRJ_SEEN%==1 (
           set SUBLINE=%%A
           goto :LOOPEND)
       if "%%A"=="project" set /A PRJ_SEEN=1
       goto :LOOPBEGIN)
   :LOOPEND
   
   :: Set the second function parameter to the first token
   :: obtained when SUBLINE is split by '.'
   FOR /F "delims=. tokens=1"  %%i IN ("%SUBLINE%") DO ( set PID=%%i)
   
   call set %~2=%PID%
   
   exit /b 

4. Insert the following code after the line setting CURL_CMD. This calls the new pid_from_analysis_page function to derive the required Project ID and return it as the value of PROJECT_ID, then uses PROJECT_ID to construct a suitable value for the PROJECT_HTML_URL variable.

   (call:pid_from_analysis_page %ANALYSIS_HTML_URL% PROJECT_ID)
   set PROJECT_HTML_URL=%HUB%/project/%PROJECT_ID%.html 

5. When you invoke the script, specify the analysis directory as the second argument.

   For example: using the hub at http://[::1]:7341, rename the project analyzed in directory whose C:\myprojects\projectX.prj_files\ to "Another Renamed Project".

   rename_project http://[::1]:7341 C:\myprojects\projectX.prj_files\ Another%20Renamed%Project

Provide credentials for a non-Anonymous user

If your hub is configured so that special user Anonymous does not have the required permissions, you will need to edit the file to submit credentials for a suitable hub user account.

See CodeSonar HTTP API: Authentication for more information on authentication strategies.

Running Batch Files Automatically

You can use your system tools to arrange for the batch file to be run automatically.

Links

• Typical CodeSonar Tasks
• HTTP API Documentation
• The CodeSonar Hub
• CodeSonar GUI Reference